Screen Saver

  1. 델파이/C++Builder에서 윈도우즈 스크린 보호기를 만드는 방법
by Mark R. Johnson
역: 정우철

델파이나 C++Builder에서 윈도우 스크린 보호기를 어떻게 만드는 지 종종 질문을 받곤 한다. 이 스크린 보호기는 제어판에서 디스플레이 설정사항에서 제어될 수 있는 일종의 프로그램이다. 뉴스그룹과 종종 부상하는 질문공세로 인해 차라리 직접 이것을 만들어 보기로 결정하였다. 아주 간단한 스크린 보호기를 델파이로 구현해 보도록 하겠다. C++Builder로 구현하는 것도 거의 비슷하기 때문에 여기서는 델파이로 구현하고 C++Builder는 직접 구현하도록 하자.

완전한 Delphi 소스 코드는 spheres.zip (4K)로 다운로드 받을 수 있다. 이 코드의 자세한 부분으로 들어가기 이전에 먼저 일반적인 개념과 몇몇 코드 부분에 대해 도움을 준 Thomas W. Wolf 에게 감사드린다.

배경

윈도우 스크린 보호기는 기본적으로 확장명이 .SCR로 된 표준 윈도우 실행파일이다. 제어판의 인터페이스에 제대로 동작하기위해서는 반드시 다음과 같은 몇가지 사항이 충족되어야만 한다.

  • 선택적 세팅이 유지되어야 한다.
  • 자체적으로 설명이 제공되어야 한다.
  • 활성화 모드와 실행 모드 사이에 구분이 있어야 한다.
  • 실행할 때 자신의 다중 복사복은 허락하지 않아야 한다.
  • 마우스나 키를 눌렀을 경우 프로그램은 종료되어야 한다.

다음의 설명에서 이러한 요소들을 델파이에서 어떻게 충족시켜주는 지 자세히 설명하겠다.

출발

여기서 만들 스크린 보호기는 스크린을 우선 검은 상태로 만들고 스크린 상의 임의의 위치에서 그림자진 공을 그리도록 하겠다. 유저는 최대 공의 갯수를 명시하고 그릴 공의 크기와 속도에 대해서도 생각해 둔다.

시작하기 위해서 File|New Project를 선택한다.

폼 초기화

스크린 보호기에서 대부분 볼 수 있는 첫번째 사항은 셋업 다이얼로그이다. 이것은 유저가 스크린 보호기에 특정한 옵션의 값을 명시해주도록 하는 부분이다. 이러한 폼을 만들기 위해서 Form1의 속성을 다음과 같이 바꾼다.

BorderIcons     [biSystemMenu]
  biSystemMenu  True
  biMinimize    False
  biMaximize    False
BorderStyle     bsDialog
Caption         Configuration
Height          162
Name            CfgFrm
Position        poScreenCenter
Visible         False
Width           266

스크린 상에 공의 갯수와 공의 크기, 그리고 이것들이 그려지는 속도에 대해 설정할 필요가 있기 때문에 이 다이얼로그가 필요하다. 이것이 가능하도록 다음과 같이 3개의 Labels (Standard palette) 과 SpinEdits (Samples palette) 를 놓는다.

object Label1: TLabel
  Left = 16
  Top = 19
  Width = 58
  Height = 16
  Alignment = taRightJustify
  Caption = 'Spheres:'
end
object Label2: TLabel
  Left = 41
  Top = 59
  Width = 33
  Height = 16
  Alignment = taRightJustify
  Caption = 'Size:'
end
object Label3: TLabel
  Left = 29
  Top = 99
  Width = 45
  Height = 16
  Alignment = taRightJustify
  Caption = 'Speed:'
end
object spnSpheres: TSpinEdit
  Left = 84
  Top = 15
  Width = 53
  Height = 26
  MaxValue = 500
  MinValue = 1
  TabOrder = 0
  Value = 50
end
object spnSize: TSpinEdit
  Left = 84
  Top = 55
  Width = 53
  Height = 26
  MaxValue = 250
  MinValue = 50
  TabOrder = 1
  Value = 100
end
object spnSpeed: TSpinEdit
  Left = 84
  Top = 95
  Width = 53
  Height = 26
  MaxValue = 10
  MinValue = 1
  TabOrder = 2
  Value = 10
end

마지막으로 3개의 buttons 을 놓는다.-- OK, Cancel, Test. Test 버튼은 스크린 보호기 설정 다이얼로그의 표준은 아니지만 구현하고 매우 쉽고 편리한 것이다.

object btnOK: TBitBtn
  Left = 153
  Top = 11
  Width = 89
  Height = 34
  TabOrder = 3
  Kind = bkOK
end
object btnCancel: TBitBtn
  Left = 153
  Top = 51
  Width = 89
  Height = 34
  TabOrder = 4
  Kind = bkCancel
end
object btnTest: TBitBtn
  Left = 153
  Top = 91
  Width = 89
  Height = 34
  Caption = 'Test...'
  TabOrder = 5
  Kind = bkIgnore
end

일단 이와같은 골격을 갖추었다면 이제 할일은 코딩만 남았다. 먼저 현재의 설정을 읽어오고 저장할 수 있는 방법이 필요하다. 유저 윈도우 디렉토리에 initialization file (*.INI)로서 저장할 수 있다. 델파이에서는 TIniFile 오브젝트를 이용하면 이것을 간단히 해결할 수 있다.

이 오브젝트를 이용하기 위해서는

uses
  IniFiles;

을 추가하고 TCfgFrm 의 private 선언부에 프로시저를 다음과 같이 선언한다.

    procedure LoadConfig;
    procedure SaveConfig;

이제 구현부에 대해서는 다음과 같이 작성하면 된다.

const
  CfgFile = 'SPHERES.INI';

procedure TCfgFrm.LoadConfig;
var
   inifile : TIniFile;
begin
  inifile := TIniFile.Create(CfgFile);
  try
    with inifile do begin
      spnSpheres.Value := ReadInteger('Config', 'Spheres', 50);
      spnSize.Value    := ReadInteger('Config', 'Size', 100);
      spnSpeed.Value   := ReadInteger('Config', 'Speed', 10);
    end;
  finally
    inifile.Free;
  end;
end; {TCfgFrm.LoadConfig}

procedure TCfgFrm.SaveConfig;
var
   inifile : TIniFile;
begin
  inifile := TIniFile.Create(CfgFile);
  try
    with inifile do begin
      WriteInteger('Config', 'Spheres', spnSpheres.Value);
      WriteInteger('Config', 'Size', spnSize.Value);
      WriteInteger('Config', 'Speed', spnSpeed.Value);
    end;
  finally
    inifile.Free;
  end;
end; {TCfgFrm.SaveConfig}

설정 다이얼로그에 나머지 부분은 어떻게 이벤트에 동작하느냐하는 문제인데 먼저 설정 다이얼로그는 프로그램이 시작하자마자 동작되도록 한다. 이것은 폼의 OnCreate 이벤트에서 해주면 된다.

procedure TCfgFrm.FormCreate(Sender: TObject);
begin
  LoadConfig;
end; {TCfgFrm.FormCreate}

다음으로, OK 버튼에 대해서는 현재의 설정을 저장한다는 것이므로 다음과 같이 작성하면 된다.

procedure TCfgFrm.btnOKClick(Sender: TObject);
begin
  SaveConfig;
  Close;
end; {TCfgFrm.btnOKClick}

Cancel일 경우는 단지 폼을 종료시키면 된다. l

procedure TCfgFrm.btnCancelClick(Sender: TObject);
begin
  Close;
end; {TCfgFrm.btnCancelClick}

마지막으로, 스크린 보호기에 대한 테스트는 다음과 같이 Show 메소드를 쓰면 스크린 보호기폼이 바로 나타나게 되는 것이다.

procedure TCfgFrm.btnTestClick(Sender: TObject);
begin
  ScrnFrm.Show;
end; {TCfgFrm.btnTestClick}

스크린 보호기 폼

스크린 보호기 그 자체는 단순히 크고, 검고, 캡션이 없고 스크린 전체를 뒤집어 쓴 하나의 폼이다. 이 폼을 만들기 위해 새로운 폼을 선택하고 다음과 같이 속성을 정한다.

BorderIcons     []
  biSystemMenu  False
  biMinimize    False
  biMaximize    False
BorderStyle     bsNone
Color           clBlack
FormStyle       fsStayOnTop
Name            ScrnFrm
Visible         False

이 폼에 단지 TTimer라는 컴포넌트를 추가한다. 그리고 다음과 같이 속성을 정한다.

object tmrTick: TTimer
  Enabled = False
  OnTimer = tmrTickTimer
  Left = 199
  Top = 122
end

이 폼에서는 다른 컴포넌트는 필요없다. 하지만 그림자진 공을 그리기 위해서 몇줄의 코딩은 필요하다. TScrnFrm 의 private 섹션에 다음의 프로시저를 선언한다.

    procedure DrawSphere(x, y, size : integer; color : TColor);

이제,구현부에서는 다음과 같이 코딩한다.

procedure TScrnFrm.DrawSphere(x, y, size : integer; color : TColor);
var
  i, dw    : integer;
  cx, cy   : integer;
  xy1, xy2 : integer;
  r, g, b  : byte;
begin
  with Canvas do begin
    {펜과 브러시로 그린다.}
    Pen.Style := psClear;
    Brush.Style := bsSolid;
    Brush.Color := color;
    {Prepare colors for sphere.}
    r := GetRValue(color);
    g := GetGValue(color);
    b := GetBValue(color);
    {공을 그린다.}
    dw := size div 16;
    for i := 0 to 15 do begin
      xy1 := (i * dw) div 2;
      xy2 := size - xy1;
      Brush.Color := RGB(Min(r + (i * 8), 255), Min(g + (i * 8), 255),
                         Min(b + (i * 8), 255));
      Ellipse(x + xy1, y + xy1, x + xy2, y + xy2);
    end;
  end;
end; {TScrnFrm.DrawSphere}

코드를 보면 알 수 있듯이, (x,y) 위치를 지정하였다. 뿐만 아니라 기본 색깔과 대각선 방향도 정했다. 공을 그리기위해 점차로 밝은 색깔로 브러쉬를 사용하여 그렸다.

여기서 함수 Min()이란 것을 볼 수가 있는데 이것은 델파이 표준 함수는 아니다. 따라서 DrawSphere() 위에 부분에 다음과 같이 정의하였다.

function Min(a, b : integer) : integer;
begin
  if b < a then
    Result := b
  else
    Result := a;
end; {Min}

DrawSphere() 함수를 제시간에 호출하기 위해 타이머의 OnTimer 이벤트에 다음과 같이 코딩한다.

procedure TScrnFrm.tmrTickTimer(Sender: TObject);
const
  sphcount : integer = 0;
var
  x, y    : integer;
  size    : integer;
  r, g, b : byte;
  color   : TColor;
begin
  if sphcount > CfgFrm.spnSpheres.Value then begin
    Refresh;
    sphcount := 0;
  end;
  Inc(sphcount);
  x := Random(ClientWidth);
  y := Random(ClientHeight);
  size := CfgFrm.spnSize.Value + Random(50) - 25;
  x := x - size div 2;
  y := y - size div 2;
  r := Random($80);
  g := Random($80);
  b := Random($80);
  DrawSphere(x, y, size, RGB(r, g, b));
end; {TScrnFrm.tmrTickTimer}

이 프로시저는 공의 수를 추적해 스크린 상에서 생성되고 제거되는 공의 수를 알아서 처리해 주는 부분이다. 결국, 난수로 크기나 색깔 다음에 그려질 공은 이 코딩 부분을 통해 제어되는 것이다.

설정 폼인 CfgFrm 폼이 메인 유닛에서 인식될 수 있게 하기 위해서는 uses 절에 다음과 같이 유닛을 추가해야 한다.

uses
  Cfg;

다음으로 할일은 스크린 보호기에서 마우스나 키가 눌려졌을 경우 혹은 마우스가 움직일 경우 종료하는 부분을 만들어야 한다. 이것을 할 수 있는 것은 Application.OnMessage 이벤트를 사용하면 된다.

먼저, 다음의 변수를 추가한다.

var
  crs : TPoint;

이 변수는 나중에 비교할 때 사용하기 위해 마우스 현재 위치를 저장한다. TScrnFrm의 private 섹션에 다음을 추가해 보자.

    procedure DeactivateScrnSaver(var Msg : TMsg; var Handled : boolean);

다음의 코드는 이 프로시저에 대한 구현부이다.

procedure TScrnFrm.DeactivateScrnSaver(var Msg : TMsg; var Handled : boolean);
var
  done : boolean;
begin
  if Msg.message = WM_MOUSEMOVE then
    done := (Abs(LOWORD(Msg.lParam) - crs.x) > 5) or
            (Abs(HIWORD(Msg.lParam) - crs.y) > 5)
  else
    done := (Msg.message = WM_KEYDOWN) or (Msg.message = WM_ACTIVATE) or
            (Msg.message = WM_ACTIVATEAPP) or (Msg.message = WM_NCACTIVATE);
  if done then
    Close;
end; {TScrnFrm.DeactivateScrnSaver}

WM_MOUSEMOVE 윈도우 메시지를 받았을 경우, 마우스의 원래 위치와 비교해 다르면 종료시키는 코딩이다.

이러한 윈도우 메시지가 적용되기 위해서는 Application.OnMessage 속성을 설정해야 하고 마우스의 원래 위치를 얻어야 한다. 폼의OnShow 이벤트 핸들러에 작성하면 좋다.

procedure TScrnFrm.FormShow(Sender: TObject);
begin
  GetCursorPos(crs);
  tmrTick.Interval      := 1000 - CfgFrm.spnSpeed.Value * 90;
  tmrTick.Enabled       := true;
  Application.OnMessage := DeactivateScrnSaver;
  ShowCursor(false);
end; {TScrnFrm.FormShow}
procedure TScrnFrm.FormHide(Sender: TObject);
begin
  Application.OnMessage := nil;
  tmrTick.Enabled       := false;
  ShowCursor(true);
end; {TScrnFrm.FormHide}

마지막으로 할 일은 OnActivate 이벤트 핸들러에 윈도우가 최대로 커지게 만드는 일이다.

procedure TScrnFrm.FormActivate(Sender: TObject);
begin
  WindowState := wsMaximized;
end; {TScrnFrm.FormActivate}

스크린 보호기에 대한 설명

제어판에 나타나는 텍스트를 정의하기 위해서는 {$D text} 지시어를 프로젝트 소스에 추가한다. 스크린 보호기는 반드시 "SCRNSAVE"라는 텍스트가 뒤따라 와야 한다.

{$D SCRNSAVE Spheres Screen Saver}

활성화와 설정 모드

윈도우즈는 스크린 보호 프로그램을 두가지 조건하에서 실행시킨다. 1) 스크린 보호기가 활성화되고 2)스크린 보호기가 설정사항이 정해질 때, 양쪽 모두 윈도우즈는 똑같은 프로그램을 실행시킨다. 커맨드 라인에서 "/s"는 활성화 모드로 "/c"는 설정 모드로 설정한다.

메인 폼 선언

이상적으로 한다면 ScrnFrm을 메인 폼으로 한다. 이 경우 활성화 모드이므로 인자는 /s 로 나타나고 메인 폼이 스크린 화면으로 나타난다. 반대인 경우 설정 폼을 메인 폼으로 한다.

begin
  if (ParamCount > 0) and (UpperCase(ParamStr(1)) = '/S') then begin
    {ScrnFrm needs to be the Main Form.}
    Application.CreateForm(TScrnFrm, ScrnFrm);
    Application.CreateForm(TCfgFrm, CfgFrm);
  end else begin
    {CfgFrm needs to be the Main Form.}
    Application.CreateForm(TCfgFrm, CfgFrm);
    Application.CreateForm(TScrnFrm, ScrnFrm);
  end;
  Application.Run;
end.

UpperCase() 를 사용하기 위해서는 SysUtils 유닛이 첨가되어야 한다.

uses
  Forms, SysUtils,
  Scrn in 'SCRN.PAS' {ScrnFrm},
  Cfg in 'CFG.PAS' {CfgFrm};

다중 인스턴스 방지

스크린 보호기 중에서 한 가지 주의해야 할 점은 다중의 인스턴스를 방지해야 한다는 점이다. 그렇지 않으면 윈도우즈는 계속해서 이 프로그램을 발생시키기 때문에 문제가 커진다.

다중 인스턴스를 방지하는 방법은 프로젝트 소스 파일에서 다음의 문장을 추가하면 된다.

begin
  {오직 하나의 인스턴스만 실행}
  if hPrevInst = 0 then begin
    if (ParamCount > 0) and (UpperCase(ParamStr(1)) = '/S') then begin
      ...
    end;
    Application.Run;
  end;
end;

hPrevInst 변수는 델파이에서 제공되는 전역 변수로서 현재의 프로그램에 대한 이전 인스턴스를 가르킨다. 만약 0이면 이전에 실행되는 프로그램이 없음을 의미한다.

어떤 커맨드 라인 파라미터 없이도, 이 프로그램은 기본적으로 설정 모드를 지정해 주고 있다. "/s" 를 첫번째 인자로 전달해 준다.

스크린 보호기 설치하기

스크린 보호기에 대해 테스트하고 디버거 과정이 끝났다면, 이제 실제로 설치하는 일만 남았다. 실행 파일(SPHERES.EXE) 을 확장명만 .SCR로 바꾼다음(SPHERES.SCR) Windows 디렉토리나 system 디렉토리에 복사해놓으면 된다. 그리고 나머지 할 일은 제어판에서 Display를 선택하고 스크린 보호기를 이 실행파일로 선택하기만 하면 모든 설치는 끝난다.

Copyright © 1995 Mark R. Johnson. This is a CITY ZOO production.
Last revised September 4, 1995